Migrating to Mac OS X

[Philippe Martin]

At 15:38 +1300 07/02/02, Peter Thirkell wrote:
>I am switching over to OS X and have a virgin copy of Frontier installed and
>running sweetly. I now want to migrate all my Manila sites across from OS 9
>to the OS X environment.
>
>Is there any documentation that describes how best to do this? Can I simply
>for example replace config.root and ManilaWebsites.root (virgin installs)
>with my earlier config.root and ManilaWebsites.root - or will this "break"
>something else?
>
>All my basic IP settings, domains etc are theoretically unchanged in the
>switch to OS X - altho Frontier now sits in the "Applications" folder
>whereas previously it was at the top level of my hard drive. And what
>happens if I change the name of the hard drive?

That's the main problem: every addresses are broken, in your databases.

Here's the script I use to fix all the address objects in the selected table (you should be able to copy from here and paste into a script, but let me know if you can't and I'll send you the script).

HTH.

Philippe



«2000/03/07 by Philippe Martin.
  «Description:
    «Run this to fix all the addresses in the selected table and its subtables at any level.
    «Can convert addresses from PC to Mac and vice-versa, or from one Mac to another and from one PC to another.
  «Parameters:
    «
  «Return:
    «
  «Errors:
    «
  «Revisions:
    «2001/11/27 by Philippe Martin.
      «Fixed an error that occurred when an address was pointing to a file but not to an object. Now, in this case, the address isn't updated but there's no longer an error.
«~~~~~~~~~~~~~~~~~~~~~~~~
on convertAddresses () {
  on visitTab( adrTable ) {
    local (adrItem );
    local (adr, lsPath, pathItem, newAdr);
    for adrItem in adrTable {
      case true {
        typeOf ( adrItem^ ) == tableType {
          visitTab( adrItem )};
        typeOf( adrItem^ ) == addressType {
          adr = string( adrItem^ );
          if not defined( adr^ ) { // may be a remote address
            lsPath = string.parseAddress( adr );
            if sizeOf( lsPath ) > 1 {
              newAdr = @[ lsPath[ 2 ] ];
              if defined( newAdr^ ) {
                try {
                  for i = 3 to sizeOf( lsPath ) {
                    newAdr = @newAdr^.[ lsPath[ i ] ]};
                  adrItem^ = newAdr;
                  n++;
                  msg( "Fixed: " + string( newAdr ) )}}}}}}
      else {
        continue}};
    return true};
 
  local ( n = 0 );
  local ( adrStart = table.getCursor( ) );
  if typeOf( adrStart^ ) != tableType {
    scriptError( "Select a table and try again." )};
 
  if not dialog.confirm( "Fix all addresses in \"" + adrStart + "\"?" ) { return };
  visitTab( adrStart );
  msg( "Fixed " + n + " addresses." )};
bundle { // test
  convertAddresses( )}
-- 

____________________________________________________________________
 Philippe MARTIN
 mailto:philippemartin at wanadoo.fr